home *** CD-ROM | disk | FTP | other *** search
/ UpTime Volume 1 #6 / utv1n6s1.d64 / ring of elanor (.txt) < prev    next >
Commodore BASIC  |  2022-08-28  |  7KB  |  232 lines
  1. 5 sys 65418:poke 808,234:poke56,160:clr
  2. 10 dim sp$(4)
  3. 20 poke53280,11:poke53281,0:print"[147]"
  4. 25 print"[150]     ****  [212]he [210]ing of [197]lanor  ****"
  5. 30 print" [158][200]ath thou a persona on disk? ";:gosub 2200
  6. 40 if t$="y" then print"[217]es":goto 1770
  7. 45 print"[206]ay"
  8. 50 print" [196]urst thou wish to hear the story of    the [204]and of [197]lanor? ";
  9. 60 gosub 2200:if t$="n" then print"[206]ay":goto 510
  10. 65 print"[217]es"
  11. 70 a$="[147]      [212]he [211]tory of [197]lanor...":gosub 2500
  12. 80 a$="[155]   [201]n days long past, the world was not":gosub 2500
  13. 90 a$="as we know it.  [193]mong mortal men walked":gosub 2500
  14. 100 a$="the [200]orrors of [195]haos: [196]ragons, [196]emons,":gosub 2500
  15. 110 a$="and other dwelleres of darkness.  [194]ut":gosub 2500
  16. 120 a$="then a great [215]arrior-[195]leric emerged to":gosub 2500
  17. 130 a$="fight [195]haos, and with the help of his":gosub 2500
  18. 140 a$="two brothers, he banished [195]haos and all":gosub 2500
  19. 150 a$="its minions from the world of mortal":gosub 2500
  20. 160 a$="men.":gosub 2500:fort=1to250:nextt
  21. 170 a$="     [200]is name was [197]lric the [204]awful.":gosub 2500:gosub 2300
  22. 180 a$="[147][155]   [200]e founded the [195]entral [214]illage of":gosub 2500
  23. 190 a$="[200]omeland, for rest and protection.  [201]n":gosub 2500
  24. 200 a$="the village a great statue was built in":gosub 2500
  25. 210 a$="his honor and form. [212]he [194]rothers of [204]aw":gosub 2500
  26. 220 a$="(as [197]lric and his brothers had become":gosub 2500
  27. 230 a$="known) created the [199]reat [210]ing of [197]lanor[155]":gosub 2500
  28. 240 a$="as protection for the land after their":gosub 2500
  29. 250 a$="death.  [212]he ring was placed on the":gosub 2500
  30. 260 a$="statue of [197]lric and maintained a lawful":gosub 2500
  31. 270 a$="shield around our world that kept [195]haos":gosub 2500
  32. 280 a$="at bay.  [193]s long as the ring stayed, so":gosub 2500
  33. 290 a$="would the peace.":gosub 2500:gosub 2300
  34. 300 a$="[147][155]   [212]he ring was successful for many":gosub 2500
  35. 310 a$="generations until it mysteriously":gosub 2500
  36. 320 a$="vanished.  [206]ow, the [197]vil slowly seeps":gosub 2500
  37. 330 a$="back to our world and will soon overrun":gosub 2500
  38. 340 a$="us if left unchecked.  [193]s we speak, men":gosub 2500
  39. 350 a$="and women are being slaughtered by the":gosub 2500
  40. 360 a$="[196]emons.":gosub 2500
  41. 380 a$="   [201]t is rumored that the greatest of":gosub 2500
  42. 390 a$="the [197]vil beasts has the ring and plans":gosub 2500
  43. 400 a$="to harness its power against the very":gosub 2500
  44. 405 a$="people it was meant to protect.":gosub 2500:gosub 2300
  45. 410 a$="[147]   [215]ill the [196]ragons rule the humans?":gosub 2500
  46. 420 a$="[195]an the mortals of the world ever be":gosub 2500
  47. 430 a$="free of [195]haos again? [155] [215]ell, my friend,":gosub 2500
  48. 440 a$="the answers lie in you.  [217]ou are our":gosub 2500
  49. 450 a$="last hope.  [212]he fate of humanity rests":gosub 2500:fort=1to250:next
  50. 460 a$="upon your shoulders.":gosub 2500
  51. 470 a$="   [199]o now, and may the spirit of [197]lric":gosub 2500
  52. 480 a$="the [204]awful[155] protect you.":gosub 2500:gosub 2300
  53. 510 print"[154][147]         [195]haracter [195]onstruction"
  54. 520 print:print
  55. 530 print"[152] [215]hat durst thy name?"
  56. 540 print
  57. 550 print"[152]>[159]";:gosub 3000
  58. 560 if t$=""then print"[145]";:goto 550
  59. 570 cn$=left$(t$,8)
  60. 572 x$="":for i=1 to len(cn$):a$=mid$(cn$,i,1)
  61. 574 if asc(a$)>192 and asc(a$)<219 then a$=chr$(asc(a$)-128)
  62. 576 x$=x$+a$:next
  63. 580 print
  64. 590 print"[152] [215]hat manner of man are ye?"
  65. 595 print " ([197]lf, [195]leric, or [200]uman)"
  66. 600 print">[159][164]";
  67. 605 get t$:if t$="" then 605
  68. 607 if t$="" then ss=-255
  69. 610 if t$<>"e"and t$<>"h"and t$<>"c"then605
  70. 611 print"[157]";
  71. 612 if t$="e" then r$="[197]lf":printr$
  72. 614 if t$="c" then r$="[195]leric":printr$
  73. 616 if t$="h" then r$="[200]uman":printr$
  74. 620 print
  75. 630 l=1:print"[151][204]evel ";l
  76. 640 print
  77. 650 s=int(rnd(1)*14)+1:if r$="[200]uman"then s=s+4:if s>15then s=15
  78. 660 if r$="[195]leric"then s=s-2:if s<1then s=1
  79. 670 i=int(rnd(1)*14)+1:if r$="[195]leric"then i=i+2:ifi>15theni=15
  80. 680 c=int(rnd(1)*14)+1:if r$="[200]uman"thenc=c-2:ifc<1thenc=1
  81. 690 d=int(rnd(1)*14)+1:ch=int(rnd(1)*14)+1
  82. 700 sl=int(rnd(1)*40)+50:ex=0
  83. 710 hp=int(rnd(1)*c)+4:h=hp
  84. 720 if r$="[197]lf"thenac=6
  85. 730 if r$="[200]uman"thenac=5
  86. 740 if r$="[195]leric"thenac=7
  87. 750 ifs+d>22thenac=ac-2
  88. 760 print"[152] [211]trength    -[155]";s;"[157] [152]"
  89. 770 print" [201]ntelligence-[155]";i;"[157] [152]"
  90. 780 print" [195]onstitution-[155]";c;"[157] [152]"
  91. 790 print" [196]exterity   -[155]";d;"[157] [152]"
  92. 800 print" [195]harisma    -[155]";ch;"[157] [152]"
  93. 810 print" [200]it [208]oints  -[155]";hp;"[157] [152]"
  94. 820 print" [193]rmour [195]lass-[155]";ac;"[157] [152]"
  95. 830 print:print
  96. 840 ifss>3then870
  97. 850 printtab(11)"[158][193]rt ye satisfied?":gosub 2200
  98. 860 if t$="n"thenss=ss+1:print"[145][145][145][145][145][145][145][145][145][145][145]":goto650
  99. 870 print"[147]";
  100. 880 print"                         [146]"
  101. 890 print" [146]*** [195]haracter [211]heet *** [146]"
  102. 900 print"                                       [146]"
  103. 910 fort=1to7:print" [146]                                      [146]":nextt
  104. 920 print"                                       [146]"
  105. 930 print""
  106. 940 printtab(19)" [146]"
  107. 950 print" [206]ame:   [158]";cn$;tab(19)" [146]";" [211]trength:    [158]";s
  108. 960 print" [210]ace:   [158]";r$;tab(19)" [146]";" [201]ntelligence:[158]";i
  109. 970 print" [204]evel: [158]";l;tab(19)" [146]";" [195]onstitution:[158]";c
  110. 980 print" [211]ilver:[158]";sl;tab(19)" [146]";" [196]exterity:   [158]";d
  111. 990 print" [197]xper: [158]";ex;tab(19)" [146]";" [195]harisma:    [158]";ch
  112. 1000 printtab(19)" [146]"
  113. 1010 print
  114. 1020 print"                                       [146]"
  115. 1030 print" [146] [200]it [208]oints:[158]";hp;tab(19);"  [193]rmour [195]lass:[158]";ac;tab(38)" [146]"
  116. 1040 print"                                       [146]"
  117. 1050 if r$="[197]lf"then ns=2
  118. 1060 if r$="[200]uman"then ns=1
  119. 1070 if r$="[195]leric"then ns=3
  120. 1080 print
  121. 1090 if int(i/5)=>2then1310
  122. 1100 if int(i/5)=1then 1210
  123. 1110 for t=1to ns
  124. 1120 r=int(rnd(1)*4):if r=0then sp$(t)="[205]agic [205]issle"
  125. 1130 if r=1then sp$(t)="[195]reate [198]ood"
  126. 1140 if r=2then sp$(t)="[204]ight"
  127. 1150 if r=3then sp$(t)="[200]ealing"
  128. 1160 if t=1then 1190
  129. 1170 if sp$(t)=sp$(t-1) then 1120
  130. 1180 if t=3and sp$(t)=sp$(t-2)then 1120
  131. 1190 next t
  132. 1200 goto1400
  133. 1210 for t=1to ns
  134. 1220 r=int(rnd(1)*4):if r=0then sp$(t)="[201]nvisibility"
  135. 1230 if r=1 then sp$(t)="[195]reate [198]ood"
  136. 1240 if r=2 then sp$(t)="[200]ealing"
  137. 1250 if r=3 then sp$(t)="[215]eb"
  138. 1260 if t=1 then 1290
  139. 1270 ifsp$(t)=sp$(t-1)then1220
  140. 1280 if t=3and sp$(t)=sp$(t-2)then1220
  141. 1290 next t
  142. 1300 goto1400
  143. 1310 fort=1tons
  144. 1320 r=int(rnd(1)*4):ifr=0then sp$(t)="[198]ireball"
  145. 1330 if r=1then sp$(t)="[195]reate [198]ood"
  146. 1340 if r=2then sp$(t)="[200]aste"
  147. 1350 if r=3thensp$(t)="[211]uper [200]eal"
  148. 1360 if t=1then 1390
  149. 1370 if t=3and sp$(t)=sp$(t-2)then1320
  150. 1380 if sp$(t)=sp$(t-1)then 1320
  151. 1390 next t
  152. 1400 print"[211]pells:[158]"
  153. 1410 for t=1to ns
  154. 1420 print" ";sp$(t)
  155. 1430 nextt
  156. 1440 print:print"   [155][196]o you wish to keep this persona?"
  157. 1445 gosub 2200
  158. 1450 if t$="n"then ss=0:goto 510
  159. 1470 print" [208]ress <[210][197][212][213][210][206]>[155] when the disk is ready"
  160. 1475 gosub 2310
  161. 1478 open 15,8,15,"i0":gosub 2600
  162. 1479 print#15,"s0:"+x$
  163. 1480 open2,8,2,"0:"+x$+",s,w"
  164. 1485 gosub 2600
  165. 1490 print#2,cn$
  166. 1500 print#2,r$
  167. 1510 print#2,l
  168. 1520 print#2,sl
  169. 1530 print#2,ex
  170. 1540 print#2,s
  171. 1550 print#2,i
  172. 1560 print#2,c
  173. 1570 print#2,d
  174. 1580 print#2,ch
  175. 1590 print#2,h
  176. 1600 print#2,hp
  177. 1610 print#2,ac
  178. 1620 print#2,ns
  179. 1630 for t=1to ns:print#2,sp$(t):print#2,"1":nextt
  180. 1640 for t=1to 13:read ob$:print#2,ob$:print#2,"0":nextt
  181. 1650 print#2,0
  182. 1660 print#2,18:print#2,11:rem x,y
  183. 1670 print#2,10:print#2,0:rem food,arrows
  184. 1680 print#2,1:rem speed
  185. 1690 print#2,0:rem time
  186. 1700 close 2
  187. 1770 print"[147]                                       "
  188. 1780 fort=1to16:print"  [146]                                     [146]":nextt
  189. 1790 print"                                       [146]"
  190. 1800 print"                                    "
  191. 1810 for t=1to14: